blob: d14bf435e8e33d7a70a13f3b4a9f68c5dc10fb17 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
##
## This file is part of the "Coroutine" project and released under the MIT License.
##
## Created by Lars Kanis on 06/06/2019.
##
.text
# Using fastcall is a big win (and it's the same as how x64 works).
# In coroutine transfer, the arguments are passed in ecx and edx. We don't need
# to touch these in order to pass them to the destination coroutine.
.globl @coroutine_transfer@8
@coroutine_transfer@8:
# Save the thread information block:
pushl %fs:0
pushl %fs:4
pushl %fs:8
# Save caller registers:
pushl %ebp
pushl %ebx
pushl %edi
pushl %esi
# Save caller stack pointer:
movl %esp, (%ecx)
# Restore callee stack pointer:
movl (%edx), %esp
# Restore callee stack:
popl %esi
popl %edi
popl %ebx
popl %ebp
# Restore the thread information block:
popl %fs:8
popl %fs:4
popl %fs:0
# Save the first argument as the return value:
movl %ecx, %eax
# Jump to the address on the stack:
ret
|
